Category Archives: CoCo

Tandy/Radio Shack TRS-80 Color Computer (CoCo)

Sub-Etha graphical adventures?

Leave a reply

Around 93-94, I created a text adventure that featured black and white digitized pictures from the 1992 Atlanta CoCoFest. It was more of a “simulation” than a game — and even called itself a simulation on the splash screen. But, while browsing through the source code, I found there were quite a number of things you could “do” in the game, while the score let you know how much of it you completed.

I also found one from a Chicago CoCoFest, which seems to be complete other than missing the images. Rooms were numbers with the vendor name and description. It was kind of like “playing” one of my old CoCoFest reports. Trippy.

And a weird 3-D first-person Pac-Man game I was working on…

Now that I have Xroar running the current Ease of Use NitrOS-9 build, and have my CoCoSDC “real CoCo” hard drive image mounted as the second drive, I may finally be able to dig through all this stuff and see what else I have.

Like finding I made a Towel V1.05” — after I moved to Iowa! I have no recollection of that. Lots of stuff to get archived and posted online.

Should be fun.

MAZE.BAS for the CoCo

Leave a reply

While looking for something completely unrelated, I ended up going through some of my old BBS disks. In addition to my *ALLRAM* tape-based BBS, I worked on several other BBSes that were never completed.

One one of those disks was something called MAZE.BAS. But why would a maze game be on a BBS disk?

Running it showed me this…

The player “P” can move around the maze while the enemy “*” tries to get to you. It uses “A-S” for left and right, and “W-Z” for up and down.

Ah, now I remember. I had learned about VIDTEXT/VIDEOTEXT/whatever having control codes to move the cursor around the screen, so I was going to write a maze game to run online in the BBS. If you had a compatible terminal program, you could play an actual “action” game rather than just some text adventure or simulation.

The numbers at the bottom were diagnostics messages. X/Y and movement direction for Up/Down and Left/Right.

Interesting.

Here is the listing…

0 'PALETTE12,63:PALETTE13,0
9 CLS
10 PRINT"             #####
11 PRINT"    ##########   ##########
12 PRINT"   #           #           #
13 PRINT" ### ###### ####### ###### ###
14 PRINT" #   #                   #   #
15 PRINT" # ### ################# ### #
16 PRINT" #       #           #       #
17 PRINT" #######   #### ####   #######
18 PRINT"     #                   #
19 PRINT"     # ###### # # ###### #
20 PRINT"     # #      ###      # #
21 PRINT"     #   ####     ####   #
22 PRINT"     ###    #######    ###
23 PRINT"       ####         ####
24 PRINT"          ###########
25 MX=15:MY=1:PX=15:PY=13
30 POKE1024+(PY*32+PX),80:POKE1024+(MY*32+MX),96
31 PRINT@512-32,PX;PY;XP;YP,MX;MY;X;Y;
35 X=SGN(PX-MX):Y=SGN(PY-MY):Z=(1024+(MY*32+MX))
36 IFPEEK(Z+(Y*32))=96 THENMY=MY+Y ELSEIFPEEK(Z+Y*32+X)=96 THENMX=MX+X:GOTO39
37 IFPEEK(Z+X)=96 THENMX=MX+X:GOTO39
39 POKE1024+(MY*32+MX),42
40 A$=INKEY$:IFA$=""THEN55
45 IFA$="W"THENYP=-1:XP=0 ELSEIFA$="Z"THENYP=+1:XP=0
50 IFA$="A"THENXP=-1:YP=0 ELSEIFA$="S"THENXP=+1:YP=0
55 IFPEEK(1024+(PY*32+PX)+(32*YP)+XP)=96 THENPOKE(1024+PY*32+PX),96:PX=PX+XP:PY=PY+YP
60 GOTO30
999 GOTO999

Using what I know about BASIC today, I would tackle this in quite a different manner.

Maybe I will, as a benchmark exercise.

Until then…

Our magazine ads, before they were typeset…

Leave a reply

While going through some random disk images, I found some text files that seem to be the Sub-Etha Software ads, before we took them to the printshop to have them typeset by a professional.

First, this looks like the first ad we planned to run in Rainbow magazine, before we got a deal to do a quarter page inside. Note the company name was going to be Forty-Two Technology and the phone # listed was before I had a dedicated line.

Multi-Basic-- Ever wonder why, with 128K or 512K, you cannot use even 32K under RS-Dos?  Well now there's MultiBasic, making possible, without adding ANY commands, the use of ALL of your CoCo3's memory by basic.  Have several programs loaded in memory at once, able to call subroutines from each other, move between each other, even load other programs from disk, all without variable loss or interruption of program flow.

Shadow BBS-- Finally, a CoCo3 RS-Dos BBS with power, speed, and flair.  Uses RS232 Pak or serial port. Features include full ANSI, X/Y Modem, 28 line 40/80 column support, 240 byte onscreen status window, software clock, up to 255 independently numbered message areas, borderlines, one-liner discussions, surveys, auto-messages, doors to external programs, user profiles, full sysop utilities, much, much more! See for yourself, call ShadowBBS HQ at (409)63-REALM.  Order thru BBS or thru: Forty-Two Technology, PO Box 4242, Lufkin, TX 75901. (409)637-7604.

Next up is the prototype for the ad we did run, featuring MultiBASIC and SHADOW BBS by Terry Todd. We didn’t have a dedicated phone number yet, so the 632-4200 was just a made up one for the mockup.

 _____________________________________________________________
 |                                                           |
 |                                                           |
 |                                                           |
 |                                                           |
 |                                                           |
 |                                                           |
 | MULTIBASIC - Use all 128K/512K of your CoCo 3 without     |
 | learning ANY new commands!  Have several programs loaded  |
 | at once sharing subroutines and variables!  Load programs |
 | without losing variables, and more!  INTRO. PRICE: $24.95 |
 |                                                           |
 | SHADOW BBS - An RS-Dos BBS with Power, Speed, and Flair!  |
 | ANSI, X/Y Modem, Clock, Surveys, AutoMessage, Up to 255   |
 | Msg Areas, User Profiles, Doors, Borderlines, Full SysOp  |
 | Utilities, and Much, Much More!  Runs on 128K CoCo 3 with |
 | Disk Drive(s), Serial Port OR RS232 pak!  Call and see    |
 | for yourself!  (409) 63-REALM        INTRO. PRICE: $34.95 |
 |                                                           |
 | Sub-Etha Software          Call or write for information! |
 |  P.O. Box 152442           Add $2.00 S&H and $3.00 C.O.D. |
 | Lufkin, TX  75901          Texas residents add 8.25% tax. |
 |  (409)  632-4200                   "Don't Panic!"         |
 |___________________________________________________________|

Next, another prototype… Much closer to what ended up being typeset and published – and even has the real phone number. These blank spots at the top where were the logo was going to go. I did these ASCII ones to show them exactly what we wanted.

 _____________________________________________________________
 |                                                           |
 |                                                           |
 |                                                           |
 |                                                           |
 |                                                           |
 |                                                           |
 |                                                           |
 |                                                           |
 |                                                           |
 |                                                           |
 |                                                           |
 |                                                           |
 |                                                           |
 |                                                           |
 |                                                           |
 |                                                           |
 | Ever  wonder  why,  with a 128K or 512K CoCo 3 you cannot |
 | even use 32K under RS-Dos?  Well, now there's MultiBasic, |
 | making  possible  without  adding ANY commands the use of |
 | your CoCo 3's "hidden" memory  by  Basic.   Have  several |
 | programs   loaded   in   memory  at  once  able  to  call |
 | subroutines from each other.  Move  between  programs and |
 | load  other  programs  from disk without variable loss or |
 | interruption of program flow.  A "must-have"  utility for |
 | Basic programmers!                                        |
 |                                                           |
 | INTRODUCTORY PRICE ............................... $24.95 |
 |                                                           |
 |                                                           |
 |                      /) Shadow  BBS (\                    |
 |    Complete RS-Dos BBS with Low Hardware Requirements!    |
 |                                                           |
 | Finally, an RS-Dos CoCo 3  BBS  with  power,  speed,  and |
 | flair!   Uses  RS232 Pak OR serial port! Features include |
 | ANSI, X/Y Modem file  transfers,  28  line  40/80  column |
 | support,  240  byte  on-screen  status  window,  software |
 | clock, up to 255 independently  numbered  message  areas, |
 | borderlines, one-liner discussions, surveys, automessage, |
 | doors to external programs,  user  profiles,  full  SysOp |
 | utilities,  and  much,  much  more!  And unlike most BBSs |
 | you've seen, no hard drive, RS232 Pak, or memory  upgrade |
 | is  required!  Shadow  BBS will run on a 128K CoCo 3 with |
 | one disk drive and a modem, yet it is capable  of  taking |
 | advantage  of  all  the hardware your system includes.  A |
 | full appreciation of Shadow BBS comes not, however,  from |
 | it's many features or it's low hardware requirements, but |
 | from the flair and smoothness of the program itself.   We |
 | want  you  to  see what this incredible BBS can do.  Call |
 | The Shadow's Realm, the official Shadow BBS HQ system, at |
 | (409)  63-REALM  (300/1200  Baud,  24  Hrs.)  and see for |
 | yourself!                                                 |
 |                                                           |
 | INTRODUCTORY PRICE ............................... $34.95 |
 |                                                           |
 |                                                           |
 |   Sub-Etha Software        Call or Write for Information! |
 |    P.O. Box 142442         Add $2.00 S&H and $2.50 C.O.D. |
 |  Lufkin, Texas 75915       Texas residents add 8.25% tax. |
 | (409) 639-ETHA [3842]              "Don't Panic!"         |
 |___________________________________________________________|

And this one, AD4.txt, is another variation:

_____________________________________________________________
|                                                           |
|                                                           |
|                                                           |
|                                                           |
|                                                           |
|                                                           |
|                                                           |
|                                                           |
|                                                           |
|                                                           |
|                                                           |
|___________________________________________________________|
||                                                         ||
||                    *: MultiBasic :*                     ||
||   More Memory for Basic without Learning New Commands!  ||
||                                                         ||
|| Ever  wonder why, with a 128K or 512K CoCo 3 you cannot ||
|| even  use  32K  under  RS-Dos?    Well,   now   there's ||
|| MultiBasic, making possible without adding ANY commands ||
|| the use of your CoCo  3's  "hidden"  memory  by  Basic. ||
|| Have  several programs loaded in memory at once able to ||
|| call  subroutines  from  each  other.    Move   between ||
|| programs  and  load  other  programs  from disk without ||
|| variable loss  or  interruption  of  program  flow.   A ||
|| "must-have" utility for Basic programmers!              ||
||                                                         ||
|| INTRODUCTORY PRICE ............................. $24.95 ||
||                                                         ||
||                                                         ||
||                     *: Shadow BBS :*                    ||
||   Complete RS-Dos BBS with Low Hardware Requirements!   ||
||                                                         ||
|| Finally, an RS-Dos CoCo 3 BBS with  power,  speed,  and ||
|| flair!  Uses RS232 Pak OR serial port! Features include ||
|| ANSI, X/Y Modem file transfers, 28  line  40/80  column ||
|| support,  240  byte  on-screen  status window, software ||
|| clock, up to 255 independently numbered message  areas, ||
|| borderlines (quotes),  one-liner  discussions, surveys, ||
|| automessage, doors to external programs, user profiles, ||
|| full  SysOp utilities, and much, much more!  And unlike ||
|| most BBSs you've seen, no hard  drive,  RS232  Pak,  or ||
|| memory  upgrade  is  required! Shadow BBS will run on a ||
|| 128K CoCo 3 with one disk drive and a modem, yet it  is ||
|| capable  of  taking  advantage of all the hardware your ||
|| system includes.  A  full  appreciation  of  Shadow BBS ||
|| comes not, however, from it's many features or it's low ||
|| hardware  requirements,  but   from   the   flair   and ||
|| smoothness  of  the program itself.  We want you to see ||
|| what this incredible BBS can  do.   Call  The  Shadow's ||
|| Realm,  the  official  Shadow  BBS  HQ system, at (409) ||
|| 63-REALM (300/1200 Baud, 24 Hrs.) and see for yourself! ||
||                                                         ||
|| INTRODUCTORY PRICE ............................. $34.95 ||
||_________________________________________________________||
|                                                           |
|    Sub-Etha Software      Call or Write for Information!  |
|     P.O. Box 152442       Add $2.50 S&H and $3.50 C.O.D.  |
|   Lufkin, Texas 75915     Texas residents add 8.25% tax.  |
|  (409) 639-ETHA [3842]    "Don't Panic -- We Ship Fast!"  |
|___________________________________________________________|

I guess by this next one we trusted the typesetting person, since it was just the raw text:

Happy Holidays From...

 SUB-ETHA SOFTWARE

"In Support of the CoCo"

Thanks to those who stopped by our booth at the CoCo Fest!

 *: MiniBanners :*
 Multiple Line Banners on ANY Printer!

NEW!  Create single or multiple line banners with adjustable heights and
widths.  Up to 16 lines of text with independently sized characters.  Even
works with daisy wheel and non-graphic printers!  Includes over 30 fonts!

INTRODUCTORY PRICE ................................................ $14.95

 *: MultiBasic :*
 More Memory for Basic without Learning New Commands! 

PRETTY NEW!  Tired of being limited to 22K for Basic?  We were too, so we
created MultiBasic, a utility which allows you to use the "hidden" memory of
your CoCo 3 without learning ANY new commands.  Load multiple programs, disk
chain, share subroutines and variables, all without interrupting program flow.

HOLIDAY PRICE ..................................................... $24.95

 *: Shadow BBS :*
 Complete RS-Dos BBS with Low Hardware Requirements!

ALSO PRETTY NEW!  Finally, an RS-Dos BBS with power, speed, and flair.  Uses
RS232 Pak OR serial port.  Does not require a hard drive or memory upgrade! 
Features:  SysOp Utilities, Up to 255 Msg Areas, X/Y Modem, ANSI, Status
Window, Clock, AutoMessage, User Surveys and Profiles, and too much more to
mention here!  A full appreciation of Shadow BBS comes not, however, from it's
many features or low hardware requirements, but from the flair and smoothness
of the program itself.  We want you to see what this BBS can do.  Call the
Shadow's Realm, the official Shadow BBS HQ, at (409) 63-REALM (300-2400 Baud,
24 Hrs.) and see for yourself!

HOLIDAY PRICE ..................................................... $34.95

I wonder what else I will find as I go through these things…

What are the odds?

Leave a reply

Back in the early 1980s, a friend of mine had TRS-80 Model III in their house. His mother was a writer, and had gotten it to use for writing books.

I believe it was this TRS-80 where I saw a version of Monopoly that taught me a strategy I had never learned as a kid:

The computer bought EVERYTHING it landed on, even if it had to mortgage properties to do so.

This simple strategy was a gamble, since you could end up with too many mortgaged properties and no source of income from rent. But. by doing this, the computer would end up owning so many random pieces it made it difficult to own a monopoly yourself.

And since then, that is how I played Monopoly. When it worked, it created some awfully long games (if no one had a monopoly to quickly drive other players bankrupt when they landed on their hotels).

In more modern times, I have watched YouTube videos concerning Monopoly strategies. They will break down the statistical odds of landing on any particular piece of property. For example, you know a pair of dice can produce values from 2 to 12. If truly random, the odds of getting a “1 and 1” should be the same as getting a “3 and 5.” Rather than focus on dice rolls, the strategies take into consideration things that alter locations: Go To Jail, Advance to Go, Take a Ride on Reading, etc.

These cards existing means there are more chances for a player to end up on Go, Reading Railroad, Jail, etc. This means the property squares after those spots have more chances of being landed on.

Board with board games. Move along…

But I digress… As Internet Rabbit Holes do, this led me to watch other videos about statistics in things like card games. In a randomly shuffled deck, there should be as much chance for the first card to be Ace of Spaces as there is for it to be Three of Clubs. It is random, after all.

For that first card drawn, that is a 1 out of 52 chance to be any card in the deck. (52 cards in the deck.)

But as a game plays on, there are fewer cards, so the odds of getting any of the remaining cards increases. For the second card drawn, you now know there is a 0% chance of getting whatever the first card is, and a 1 in 51 chance of getting any of the rest.

And so it continues…

For games like Blackjack or 21, you do not really care if it is a Ten of Diamonds or a King of Hearts or a Queen of Clubs or a Jack of Spades. They all have the value of 10 in the game. Thus, the likelihood of drawing a ten card is much higher than any other card in the deck.

You have four suits (clubs, spades, hearts, diamonds) so there are four of each card – Aces, Two through Ten, Jacks, Queens, and Kings. This means there are 16 cards in the deck that could be a value of 10 in the game. When you draw the first card, you should have a 16 in 52 chance of it being a ten card. That is about a 33% chance!

If you pay attention to what cards have been seen (either by you having it, or seeing it face up with another player), you can eliminate those cards from the possibilities — changing the odds of what you will get.

This is basically what I understand card counting to be. If you play a game, and you know you’ve seen three Kings so far (either in your hand, or played by others), you now know instead of four chances to draw a King, you only have one.

Math is hard. Make the computer do it.

I know this has been done before, and quite possible even on a Radio Shack Color Computer, but I thought it might be fun to create a program that displays the percentage likelihood of drawing a particular card from a deck. I suppose it could have the Blackjack/21 rule, where it treads 10, Jack, Queen and King the same, versus a “whole deck” rule where each card is unique (where you really need an 8 of Clubs to complete some run in poker or whatever game that does that; I barely know blackjack, and have never played poker).

I plan to play with this when I get time, but I decided to post this now in case others might want to work on it as well.

I envision a program that displays all the cards on the screen with a percentage below it. As cards are randomly drawn, that card’s percentage goes to 0% and all the others are adjusted.

It might be fun to visualize.

More to come, when time allows…

Counting characters in a string in Color BASIC

2 Replies

And so it begins…

I want to visualize some playing card statistics, and the easiest way I could think of to do this was to write a program in BASIC. Of course.

There are many approaches I can take, so as I put figure it out I will “show my work” and experiments that help me figure out which one will work best.

For my task, I will greatly simplify a deck of cards by ignoring suits (I just care if it’s an Ace, a Five, a King or whatever). I figure I can store it as a 52-character string representing each card:

A123456789JQKA123456789JQKA123456789JQKA123456789JQK

I could “shuffle” this “deck” and end up with a string in “random” order. I believe I have touched on randomizing a list in the past, and had some great suggestions in comments on how to do it better. Forgetting all of that, let’s just say I end up with as string that gets randomized.

But I digress…

The next question will be: “How many Kings are left in the deck?”

Some of you will already see I am heading down a poor path for doing this, but let’s start there anyway.

One way of counting a specific character in a string is to loop through it and use MID$ to pull out an individual character. Something like this:

FOR A=1 TO LEN(A$)
IF MID$(A$,A,1)="S" THEN C=C+1
NEXT

That would count all the “S” characters that appear in the string. Since every time MID$ is used it has to build a new string representing that portion of the original string, this should be our slowest way to do this. On a system with tons of strings in use, string manipulation gets real slow. For such a simple program, this might be fast enough.

Another approach, which was originally shown to me during a word wrap article as a submission, would be to use VARPTR to get the memory location of the 5-byte string ID memory, and then go to the memory where the string bytes are stored and use PEEK to look for them. You can find details in my earlier article on VARTPR.

The memory location that VARPTR returns will have the length of string as the first byte (byte 0), then an empty byte (byte 1, always 0), then the next two bytes will be the address where the string is stored (bytes 2 and 3) followed by a zero (byte 4). Knowing this, something like this would do the same thing as MID$:

A=VARPTR(A$)
SL=PEEK(A)
SS=PEEK(A+2)*256+PEEK(A+3)
FOR A=SS TO SS+SL-1
IF PEEK(A)=ASC("S") THEN C=C+1
NEXT

And do it faster.

VARPTR is a legal BASIC function, but it still seems nasty to reach in to string memory to do this. Thus, I came up with the idea of using INSTR. This function returns the start location of a matching string in another string, or 0 if not found:

PRINT INSTR("ABCDEFG","D")

That should print 4, since a “D” is located at the 4th position in the string.

You can also add an additional parameter which is where in the string to start searching. Doing this:

PRINT INSTR(5,"ABCDEFG","D")

…would print 0, because it starts scanning at the 5th character (just past the D) of the string, and then won’t find anymore.

I could start using INSTR with a position of 1 (first character), and if it comes back with a value other than 0, I found one. That value will be the position of the found character. I could then loop back and use that position + 1 to scan again at the character after the match. Repeat until a 0 (no more found) is returned. That lets the scan for characters be done by the assembly code of the BASIC ROM and is even faster. It looks like this:

F=0
xxx F=INSTR(F+1,A$,T$):IF F>0 THEN C=C+1:GOTO xxx

And we put them all together in a benchmark test program…

10 ' COUNTSTR.BAS
20 A$="THIS IS A STRING I AM GOING TO USE FOR TESTING. I WANT IT TO BE VERY LONG SO IT TAKES A LONG TIME TO PARSE."
30 T$="S":T=ASC(T$)
40 '
50 ' MID$
60 '
70 PRINT "MID$:";TAB(9);
80 TIMER=0:C=0
90 FOR A=1 TO LEN(A$)
100 IF MID$(A$,A,1)=T$ THEN C=C+1
110 NEXT
120 PRINT C,TIMER

130 '
140 ' VARPTR
150 '
160 PRINT "VARPTR:";TAB(9);
170 TIMER=0:C=0
180 A=VARPTR(A$)
190 SL=PEEK(A)
200 SS=PEEK(A+2)*256+PEEK(A+3)
210 FOR A=SS TO SS+SL-1
220 IF PEEK(A)=T THEN C=C+1
230 NEXT
240 PRINT C,TIMER

250 '
260 ' INSTR
270 '
280 PRINT "INSTR:";TAB(9);
290 TIMER=0:C=0:F=0
300 F=INSTR(F+1,A$,T$):IF F>0 THEN C=C+1:GOTO 300
310 PRINT C,TIMER

And running prints:

Wow, using INSTR is six times faster than MID$? And four times faster than VARPTR. Nice.

Now you know a bit about what I need to do. I need to represent cards in a deck (and be able to “draw” cards from that deck) and calculate how many of a specific card remain in the deck.

Since I do not need to track or show the suits (hearts, spaced, clubs, diamonds), I figure I could use one byte in a string.

To be continued … but in the meantime, do you have a better approach? Comment away!

BASIC and many input options…

4 Replies

Earlier this year, Jason Pittman shared a BASIC program with me that drew representations of all the letters of the alphabet. It was a cute program, and did some fancy drawing.

To select a letter, there was this block of code:

130 PMODE3,1:A$=INKEY$
140 IFA$="A"THEN410
150 IFA$="B"THEN510
160 IFA$="C"THEN590
170 IFA$="D"THEN680
180 IFA$="E"THEN750
190 IFA$="F"THEN820
200 IFA$="G"THEN900
210 IFA$="H"THEN1020
220 IFA$="I"THEN1100
230 IFA$="J"THEN1130
240 IFA$="K"THEN1220
250 IFA$="L"THEN1340
260 IFA$="M"THEN1410
270 IFA$="N"THEN1490
280 IFA$="O"THEN1560
290 IFA$="P"THEN1680
300 IFA$="Q"THEN1780
310 IFA$="R"THEN1890
320 IFA$="S"THEN2020
330 IFA$="T"THEN2100
340 IFA$="U"THEN2190
350 IFA$="V"THEN2250
360 IFA$="W"THEN2360
370 IFA$="X"THEN2440
380 IFA$="Y"THEN2490
390 IFA$="Z"THEN2550
400 GOTO130

I thought it might be fun to ask you — in the comments — to tell me how YOU would have done this. I can think of one way, that uses an Extended BASIC keyword, and another way, that would work on Color BASIC.

For a series of options that are sequential (like “A to Z”) there are certainly some options.

As a part two … what if they were not sequential? What if it was for a menu that had options like “A, B, C, D, Q, Z” or whatever? That let me think of a third way to do it to work in Color BASIC.

Comment away!

Steve Bjork TRS-80 Model 1 source code…

Leave a reply

From “The Big List of TRS-80 Software” I found two early Steve Bjork programs. These appear to be the two programs that appeared on the People’s Software tape:

PeoplesSoftware-TRS80-Model1

The first is a Bio-Rhythm program listed as biortsb.bas (which I assume the “sb” at the end is Steve Bjork):

10 REM  BIO-RHYTHM ------ BY STEVE BJORK
20 DIMA(150)
30  FORX=1TO20
40  READA(X)
50  RESTORE
60  FORX=1TO20
70  READA(X)
80  NEXTX:A=0
90  FORX=9TO20
100  A=A+A(X):A(X+11)=A
110  NEXTX
120  CLS:PRINT"    B I O - R H Y T H M"
130  PRINT:PRINT"  BY STEVE BJORK":PRINT
140  INPUT"WHO ARE YOU";A$
150  INPUT"WHAT IS YOUR BIRTHDATE (M,D,Y)";M,D,Y
160  INPUT"AND THE DATE FOR CHART (M,Y)";B,C
170  Z=((C-Y)*365)-D-A(M+20)+A(B+20)+INT((C-Y)/4)
180  IF(Y/4=INT(Y/4))*(M<3) Z=Z+1
190  IF(C/4=INT(C/4))*(B>2) Z=Z+1
200  CLS
210 PRINT@960,""
220  FORX=1TO31
230  SET(17,X):SET(18,X):SET(49,X):SET(50,X):SET(81,X):SET(82,X)
240  SET(113,X):SET(114,X)
250 SET(33,X):SET(65,X):SET(97,X)
260  NEXTX
270  FORX=17TO114
280  SET(X,0):SET(X,32)
290  NEXTX
300  FORX=0TO30STEP5
310  SET(16,X):SET(19,X):SET(48,X):SET(51,X):SET(80,X):SET(83,X)
320  SET(112,X):SET(115,X)
330  NEXTX
340  FORX=5TO30STEP5
350  PRINT@INT(X/3)*64+3,X;:PRINT@INT(X/3)*64+58,X;:
360  NEXTX
370  PRINT@713,"LOW";:PRINT@729,"LOW";:PRINT@745,"LOW";
380 PRINT@720,"C";:PRINT@736,"C";:PRINT@752,"C"
390  PRINT@ 724,"HIGH";:PRINT@740,"HIGH";:PRINT@756,"HIGH"
400  PRINT@781,"PHYSICAL";
410  PRINT@796,"EMOTIONAL";
420  PRINT@813,"MENTAL";
430  PRINT@857,"NAME------------";A$
440  PRINT@921,"BIRTHDATE-------";M;"/";D;"/";Y
450  PRINT@985,"CHART DATE------";B;"/";C;
460  IF(C/4=INT(C/Y))*(B=2) A(10)=29
470  FORX=1TOA(B+8)
480  P=Z-INT(Z/23)*23:E=Z-INT(Z/28)*28:I=Z-INT(Z/33)*33
490  S=6.28319*(P/23)
500  GOSUB660
510  SET(INT(S*13)+34,X)
520  S=6.28319*(E/28)
530  GOSUB660
540  SET(INT(S*13)+66,X)
550  S=6.28319*(I/33)
560  GOSUB660
570  SET(INT(S*13)+98,X)
580  Z=Z+1
590  NEXTX:A(10)=28
600  PRINT@832,"FOR A NEW CHART";
610  PRINT@896,;"ENTER A '1'";
620  INPUTA
630  IFA=1GOTO140
640  CLS
650  STOP
660  T=S:U=S
670  FORW=1TO7STEP2
680  U=U*T*T
690  S=S-(U/A(W))+((U*T*T)/A(W+1))
700  U=U*T*T
710  NEXTW
720  RETURN
730  DATA6,120,5040,362880,39916800,6.22702E09
740  DATA1.30767E12,3.55687E14
750  DATA31,28,31,30,31,30,31,31,30,31,30,31

The second is a Perpetual Calendar program listed as percalsb.bas:

5  REM....PERPETUAL CALENDAR PROGRAM
6  REM....FOR RADIO SHACKS TRS-80
7  REM....BY STEVE BJORK
8  DIMA(150)
9  CLS:PRINT@400,"PERPETUAL CALENDER   BY STEVE BJORK"
10 PRINT@ 448,"ENTER MONTH AND YEAR (MM,YY)";:INPUT M,Y
11  IF (M>12)+(M<1)THEN10
17  IF Y<100 THENY=Y+1900
18  RESTORE:FOR I=1 TO 12:READ V:NEXT I
19  FOR I=1 TO M:READ A$:NEXT I
20  B$=" ":L=0:IF INT(Y/4)<>(Y/4)THEN50
30  IF INT(Y/100)=(Y/100) THEN50
40  B$="LEAP-YEAR":L=1
50  T=INT((Y-1893)/4)
60  C=(Y-1893+T)/7:C=INT((C-INT(C))*7+.5)
90  RESTORE:FOR I=1 TO 12:READA(I):NEXTI:A(2)=A(2)+L
91  D=0:IF M=1 THEN 100
92  FOR I=1 TO M-1:D=D+A(I):NEXT I
100  D=(D+C)/7
110  D=INT((D-INT(D))*7+.5)
111  IF D=0THEND=7
120  CLS:PRINT@ 22,A$;"  ";Y;"  ";B$
150  T=0:FOR I=(D-2) TO 0 STEP-1:T=T+1:A(T+12)=(-I):NEXTI
160  P=1:FOR J=D TO 7:A(J+12)=P:P=P+1:NEXT J
164  RESTORE
165  W=0:FOR I=1 TO 12:READ X:NEXTI:FORI=1TO12:READB$:NEXTI
166  FOR J=8 TO 56 STEP 8:READ B$:PRINT@64+J,B$:NEXTJ
167  A$=" ":H=0:READ A,A$:IF A=0 THEN 170
168  IF INT(A)<>M THEN167
169  H=INT((A-INT(A))*100+.5)
170  FOR I=128 TO 832 STEP 128
180  P=0:FOR J=8 TO 56 STEP 8:S=I+J
190  P=P+1:Q=A(P+12)+(W*7)
191  Z=0:IF Q<10 THENZ=1
200  IF (Q<=0)+(Q>A(M))THEN220
210  PRINT@ S+Z,Q
211  IF H<>Q THEN 220
212  PRINT@ S+63,A$
220  NEXT J:W=W+1:NEXT I
270  END
1000  DATA31,28,31,30,31,30,31,31,30,31,30,31
1100  DATAJANUARY,FEBRUARY,MARCH,APRIL,MAY,JUNE,JULY,AUGUST
1200  DATASEPTEMBER,OCTOBER,NOVEMBER,DECeMBER
1300  DATASUN,MON,TUE,WED,THU,FRI,SAT
1400  REM...HOLIDAYS (M.D)
1500  DATA1.01,NEW YR,12.25,XMAS,2.14,VAL,7.04, 4TH,4.01,FOOL
1510  DATA10.31,HAL'WN
1800  DATA0,END

I have so far been unable to locate additional information on People’s Software, but it was produced by:

  • computer information exchange, inc.
  • box 158
  • san luis rey ca 92068

Can you find more about them?

Until then…